Moving Window Asian Option

From ThetaWiki

Overview

A moving window Asian option (MWAO) is interesting because it is challenging to evaluate. However, the description of a MWAO is simple and uses the same moving average calculation used in stock price charting. Similar to an American option which pays the difference between the current underlying price and a fixed strike, the MWAO pays the difference between the current stock price and a moving average. Since the computation of moving averages is well established, this option is also an interesting example for a new option type.

The computational difficulty of computing the Black-Scholes price of a MWAO comes from the underlying option being a discretely-sampled moving average of its stock prices. This leads to very high dimensionality int the equation for the optimal early exercise strategy. Theta Suite can deal with this high-dimensional problem easily since it was developed in a way which avoids the so-called curse of dimensionality.

Implementation in ThetaScript

model mwao
    import S	"Stock Value"
    import EUR	"Numeraire"
    import m	"Window length"
    import n	"Number of observations"
    import T	"Maturity time"
    export V	"Option process"
    export P	"Option price"
    export A	"Current average"
 
    P=V!
    deltaT = 1/250
 
    % Computing the moving average A
    C=0
    A=0
    fork
        index = m
        loop n
            A=A+ S/m - C[index]/m
            C[index] = S
            index= mod(index, m)+1
 
    		Theta deltaT
        end
    end
 
    % The American option
    Theta deltaT*(m-1)
 
    loop n-m+1
    	% Only compute values for in-the-money paths
        if (A > S)
            % Compute optimal early exercise
            if (A-S)*EUR > E(V!)
                % Exercise option
                V = max( A - S, 0)*EUR
            end            
        end        
        Theta deltaT
    end
    % Exercise option at maturity
    V = max(A-S,0)*EUR
end

Numerical Example

An option with the following parameters has a value of about 7.65.

Parameter	Symbol	Value
Option type		Moving Window Asian Option
Maturity	T	0.4 years
Risk free rate	r	5 % p.a.
Volatility	sigma	40 % p.a.
Daily observations	Delta_t	1/250 years
Early exercise		at each observation with years
Length of observation	m	10 days
Exercise value